// 环境初始化。
// 此方法在软件启动时，被系统调用一次。
void setup(){
  // 定义字符串数组
  String[] trees = { "ash", "oak" };
  // 调用append()方法，
  // 将"maple"插入字符串数组trees的尾部
  // append()方法第一个参数为目标数组，
  // 第二个参数是要添加的数组元素
  trees = append(trees, "maple");
  // 打印字符串数组trees
  printArray(trees);
}
// 画图。
// 此方法被系统默认循环调用。
void draw(){
  // 此处无代码
}

// 环境初始化。
// 此方法在软件启动时，被系统调用一次。
void setup(){
  // 定义String类型数组trees
  String[] trees = { "lychee", "coconut", "fig" };
  // 调用shorten()方法，
  // 删除trees最后一个数据项"fig"，
  // 返回一个新的数据，
  // 并重新赋值给trees。
  trees = shorten(trees);
  // 打印数组trees
  printArray(trees);
}
// 画图。
// 此方法被系统默认循环调用。
void draw(){
  // 此处无代码
}

// 定义数组x
int[] x = new int[100];
// 定义计数变量
// 此变量记录了当前x数组
// 共保存了多少个鼠标x轴坐标值
int count = 0;
// 环境初始化。
// 此方法在软件启动时，被系统调用一次。
void setup() {
  // 设置窗口大小
  size(100, 100);
}
// 画图。
// 此方法被系统默认循环调用。
void draw() {
  // 将鼠标x轴坐标值
  // 存入数组x中
  x[count] = mouseX;
  // 鼠标x轴坐标值计数+1
  count++;
  // 如果技术变量等于数组x的容量，
  // 此时说明数组x容量已满，
  // 需要对数组x进行扩容。
  // 扩容的范围是将当前容量翻倍。
  // 例如数组x初始容量为100，
  // 则第一次扩容后为200，第二次为400，
  // 以此类推。
  if (count == x.length) {
    // 对数组x进行扩容
    x = expand(x);
    // 每次扩容完毕，
    // 则打印当前数组x的容量值
    println(x.length);
  }
}

// 环境初始化。
// 此方法在软件启动时，被系统调用一次。
void setup() {
  // 设置窗口的大小
  size(100, 100);
  // 定义String类型数组north
  String[] north = { "OH", "IN", "MI" };
  // 定义String类型数组south
  String[] south = { "GA", "FL", "NC" };
  // 将数组north内容拷贝至数组south
  arrayCopy(north, south);
  // 打印数组south内容
  printArray(south);
}
// 画图
// 此方法被系统默认循环调用
void draw() {
  // 此处无代码。开心不？
}

// 定义Ring类型数组，
// 数组变量名为rings
Ring[] rings;
// 定义rings数组容量为50 
int numRings = 50;
// 记录当前屏幕上已经显示的rings的个数
int currentRing = 0;
// 环境初始化。
// 此方法在软件启动时，被系统调用一次。
void setup() {
  // 设定窗口的大小
  size(100, 100);
  // 创建Ring类型数组
  rings = new Ring[numRings];
  // 为数组rings的每一个数据项创建对象
  for (int i = 0; i < rings.length; i++) {
    // 创建类型为Ring的对象
    rings[i] = new Ring();
  }
}
// 画图。
// 此方法被系统默认循环调用。
void draw() {
  // 设置窗口背景色为黑色
  background(0);
  // 循环调用数组rings中的对象方法
  for (int i = 0; i < rings.length; i++) {
    // 调用ring对象的grow()方法
    rings[i].grow();
    // 调用ring对象的display()方法
    rings[i].display();
  }
}
// 当鼠标按下时，
// 系统会自动调用此方法
void mousePressed() {
  // 设置ring对象的显示坐标点为鼠标按下位置
  rings[currentRing].start(mouseX, mouseY);
  // 每显示一个ring对象，
  // 即将currentRing变量加一，
  // 以此记录当前屏幕上共显示了多少个ring对象
  currentRing++;
  // 当currentRing数值超过rings数组的范围时，
  // 即将计数变量currentRing回零。
  // 以此避免越界访问rings数组。
  // 也就是说，此处rings数组最大数为50，
  // 若currentRing加到50，访问rings[50]将会出错。
  // 将currentRing回零的目的就是避免越界访问的错误。
  if (currentRing >= numRings) {
    // 将currentRing回零
    currentRing = 0;
  }
}
// 自定义Ring类型
class Ring {
  // 定义ring的x，y坐标点
  float x, y;
  // 定义ring的直径
  float diameter;
  // 控制ring直径是否变化
  boolean on = false;
  // 初始化ring对象数据
  void start(float xpos, float ypos) {
    // 初始化ring的坐标点x，y
    x = xpos;
    y = ypos;
    // 初始化diameter直径为1
    diameter = 1;
    // 设置ring的直径可变化
    on = true;
  }
  // 改变ring的直径
  void grow() {
    if (on == true) {
      // ring的直径变化幅度为每次0.5
      diameter += 0.5;
      // 如果直径大于400，
      // 则停止ring的直径增长
      if (diameter > 400) {
        // 停止ring继续变化
        on = false;
        // 重新将ring的直径设置为1
        diameter = 1;
      }
    }
  }
  // 显示ring
  void display() {
    // 若ring的直径可变化，
    // 则显示圆形
    if (on == true) {
      // ring没有填充色
      noFill();
      // 设置ring的轮廓宽度
      strokeWeight(4);
      // 设置ring的轮廓颜色
      stroke(204, 153);
      // 画ring。
      // 左边开始，前两个参数为x，y坐标
      // 后两个参数为椭圆的长直径和短直径，
      // 此处相等，故所画为圆形
      ellipse(x, y, diameter, diameter);
    }
  }
}

  // 为数组rings的每一个数据项创建对象
  for (int i = 0; i < rings.length; i++) {
    // 创建类型为Ring的对象
    rings[i] = new Ring();
  }

// 定义二维数组x
int[][] x = { {50, 0}, {61,204}, {83,51}, {69,102},
{71, 0}, {50,153}, {29, 0}, {31,51},
{17,102}, {39,204} };
// 环境初始化。
// 此方法在软件启动时，被系统调用一次。
void setup() {
  size(100, 100);
}
// 画图。
// 此方法被系统默认循环调用。
void draw() {
  // 利用二维数组x的数据，
  // 画出矩形
  for (int i = 0; i < x.length; i++) {
    fill(x[i][1]);
    rect(0, i*10, x[i][0], 8);
  }
}